你这不是高精度减法的程序吗？

这跟你的题目完全不符合。

我给你说一下算法。

这题的难点就是怎么实现N进制加法。
可以用10进制高精度加法的思想来实现N进制高精度加法。
由于10进制是逢10进1，而N进制是逢N进1。所以只要把这句：
IF s[i] >= 10 THEN BEGIN
   s[i] := s[i] - 10; s[i + 1] := s[i + 1] + 1;
END;
改成：
IF s[i] >= n THEN BEGIN
   s[i] := s[i] - n; s[i + 1] := s[i + 1] + 1;
END;
就行了。不过如果是16进制还要做好数字与字母的转换。

程序：
TYPE arr = ARRAY[1..1023] OF INTEGER;
FUNCTION n_gjdadd(x, y: STRING; n: INTEGER): STRING;
VAR
   a, b, s: arr; z, zz: STRING;
   lx, ly, l, i, k: INTEGER;
BEGIN
    lx := LENGTH(x); ly := LENGTH(y); z := '';
    IF lx > ly THEN l := lx ELSE l := ly;
    FOR i:=1 TO l + 1 DO s[i] := 0;
    FOR i:=1 TO lx DO VAL(COPY(x, lx + 1 - i, 1), a[i], k);
    FOR i:=1 TO ly DO VAL(COPY(y, ly + 1 - i, 1), b[i], k);
    FOR i:=1 TO l DO BEGIN
        s[i] := s[i] + a[i] + b[i];
        IF s[i] >= n THEN BEGIN
           s[i] := s[i] - n; s[i + 1] := s[i + 1] + 1;
        END;
    END;
    IF s[l + 1] > 0 THEN l := l + 1;
    FOR i := l DOWNTO 1 DO BEGIN
        IF s[i] < 10 THEN zz := CHR(s[i] + 48) ELSE zz := CHR(s[i] + 55);
        z := z + zz;
    END;
    n_gjdadd := z;
END;
FUNCTION opposite(x: STRING): BOOLEAN;
VAR
   i, l: INTEGER; f: BOOLEAN;
BEGIN
    l := LENGTH(x); f := TRUE;
    FOR i := 1 TO (l DIV 2) DO BEGIN
        IF COPY(x, i, 1) <> COPY(x, l + 1 - i, 1) THEN BEGIN
           f := FALSE; BREAK;
        END;
    END;
    opposite := f;
END;
VAR
   i, j, ls, n: INTEGER; m, s, t: STRING;
BEGIN
    WRITE('n:'); READLN(n);
    WRITE('number:'); READLN(m);
    s := m;
    FOR i:=1 TO 30 DO BEGIN
        t := ''; ls := LENGTH(s);
        FOR j := ls DOWNTO 1 DO BEGIN
            t := t + COPY(s, j, 1);
        END;
        s := n_gjdadd(s, t, n);
        IF opposite(s) THEN BEGIN WRITELN(i); HALT; END;
    END;
    WRITELN('no');
END.